 vidkid
|
2004-04-27 18:01:05, 조회 : 2,369, 추천 : 372 |
- Download #1 : sax2.zip (3.7 KB), Download : 65
[웹서버와의 만남 #6] XML 데이터를 RecordSet 으로 받기
안녕하세요.
vidkid입니다.
이번 강좌는 서버에서 데이터를 , 로 분리해서 보내는게 아니라 XML 형태로 데이터를 보내면
그것을 RecordSet 으로 넣어 보겠습니다.
기존에 하던 방식과 바로 전 강좌를 보면 쉽게 할 수 있습니다.
그런데 SAX 에 대해서 헤깔리신 분들이 있으실 테니..
또 하나의 SAX 예제겸 해서.. 만들어 보겠습니다.
여기서 한가지 알아두실 거는 XML 파서를 수행할때 파일이 아닌 문자열을 넣어 준다는 것입니다.
{xl.parse ...}
함수에서 바로 전 강좌는 파일의 url 을 넣어줬다는 얘기지요..
자세한 내용은 강좌를 보면서 설명하기로 하겠습니다.
- 데이터 구조 정의
action.do 파일
-----------------------------------------------------------------------
<?xml version="1.0" encoding="euc-kr"?>
<RecordSet>
<Fields>
<Field name="mid" domain="String" />
<Field name="mname" domain="String" />
<Field name="mcodes" domain="String" />
</Fields>
<Record mid="hong1234" mname="홍길동" mcodes="123456-1234351" />
<Record mid="cham1234" mname="참기름" mcodes="222222-1234351" />
<Record mid="ggae1234" mname="깨소금" mcodes="452312-1234351" />
<Record mid="hongdukke" mname="홍두깨" mcodes="000000-1234351" />
</RecordSet>
-----------------------------------------------------------------------
서버는 위와 같은 형식의 데이터를 클라이언트로 보냅니다.
여기서는 파일로 처리했으며 이름은 action.do 로 했습니다. 자바 사용자는 익숙하겠죠?
<RecordSet></RecordSet>
전체 레코드셋은 위의 RecordSet 태그에 안에 있습니다.
그리고 필드 정의는 <Fields></Fields> 태그 안에 정의 되어있고
각 필드는 <Field /> 를 써서 정의 했습니다.
마지막으로 각 레코드는 <Record /> 태그를 사용했습니다.
<Record> 태그 안에는 필드명=필드값 형태로 , 없이 필드를 나열합니다.
- 컬 작업..
프로젝트 파일을 다운받아 보시면 2개의 scurl 파일을 include 했습니다.
httplib.scurl 파일은 앞쪽의 강좌에서 언급한 내용으로 GET / POST 메소드 함수가 들어있습니다.
여기서는 {gfGetMethod} 함수를 사용합니다.
GET 방식으로 데이터를 가져 오는 함수입니다.
MySaxApp.scurl 은 아래 강좌의 DefaultHandler 에서 상속받아 핸들러를 작성한 클래스로
내용은 조금 후에 살펴보겠습니다.
우선 start.curl 파일은 보겠습니다.
start.curl 파일
-----------------------------------------------------------------------
{curl 3.0 applet}
{curl-file-attributes character-encoding = "euc-kr"}
{applet manifest = "manifest.mcurl"}
{import * from CURL.XML.SAX.PARSER}
{include "httplib.scurl"}
{include "MySaxApp.scurl"}
||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||
|| XML 스트링으로부터 레코드셋을 리턴한다.
{define-proc public {gfXML2RecordSet xml : String} : #RecordSet
let rs : #RecordSet = null
let xr:XMLReader = {SAXParser}
let handler:MySaxApp = {MySaxApp}
{xr.set-content-handler handler}
{xr.set-error-handler handler}
{try
{xr.parse {InputSource character-stream = {{StringBuf xml}.to-InputStream}}}
set rs = {handler.get-recordset}
catch file-exception:IOException do
{popup-message {value file-exception}}
catch parse-exception:SAXParseException do
{popup-message {gfGetErrorMessage parse-exception}}
}
{return rs}
}
{let command:CommandButton =
{CommandButton
label = "눌러주세요",
{on Action do
let (xml : String, error?:bool) =
{gfGetMethod
{url "action.do"},
{get-character-encoding-by-name "euc-kr"}
}
||{popup-message xml}
let rs : #RecordSet = {gfXML2RecordSet xml}
{popup-message
{RecordGrid record-source=rs}
}
}
}
}
{VBox width=600px,
command
}
-----------------------------------------------------------------------
화면에는 CommandButton 하나가 출력되고 버튼을 누르면 이벤트가 호출됩니다.
버튼 이벤트의 내용을 보면 우선..
{gfGetMethod } 함수를 사용해서 action.do 파일을 읽어옵니다.
그리고
let rs : #RecordSet = {gfXML2RecordSet xml}
{gfXML2RecordSet} 함수를 사용해서 받아온 xml String 의 내용을 argument 주고
RecordSet 을 리턴 받습니다.
마지막으로 RecordGrid 를 이용해서 화면에 표시합니다.
대부분이 gfXML2RecordSet 함수에 구현되어 있으니 함수 내용을 하나씩 확인해 보죠.
-----------------------------------------------------------------------
let xr:XMLReader = {SAXParser}
let handler:MySaxApp = {MySaxApp}
{xr.set-content-handler handler}
{xr.set-error-handler handler}
-----------------------------------------------------------------------
이 부분은 바로 전 강좌에서도 나온 SAX 파서를 사용하기 위한 준비 작업입니다.
-----------------------------------------------------------------------
{try
{xr.parse {InputSource character-stream = {{StringBuf xml}.to-InputStream}}}
set rs = {handler.get-recordset}
...
}
-----------------------------------------------------------------------
그리고
{xr.parse {InputSource character-stream = {{StringBuf xml}.to-InputStream}}}
{xr.parse} 메소드를 이용해서 파싱 작업을 수행합니다.
여기서 다른점은 이전 강좌에서는 {InputSource } 가 url 이었는데 이번에는 stream 이란 것입니다.
그 다음 줄로 파싱이 끝나면 {handler.get-recordset} 를 이용해서 레코드셋을 받습니다.
set rs = {handler.get-recordset}
물론, 우리가 정의한 핸들러에 {handler.get-recordset} 메소드가 존재해야 합니다.
이젠 핸들러를 어떻게 만들었는지만 보면 되겠군요..^^
MySaxApp.scurl 파일
-----------------------------------------------------------------------
||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||
|| TSaxApp
{define-class public MySaxApp {inherits DefaultHandler}
field public rs : #RecordSet
field public rf : #RecordFields
field public rfs : {Array-of RecordField} = {{Array-of RecordField}}
{constructor public {default}
{construct-super}
}
{method public {get-recordset}:#RecordSet
{return self.rs}
}
{method public {start-document}:void}
{method public {end-document}:void}
{method public {start-element
uri:String,
name:String,
qname:String,
atts:Attributes
}:void
{if name == "Fields" then
{self.rfs.clear}
elseif name == "Field" then
let sname : #String = {atts.get-value {atts.get-index-by-qname "name"}}
let sdomain : #String = {atts.get-value {atts.get-index-by-qname "domain"}}
let dm : Domain = {Domain.from-type String}
{if sdomain == "int" then
set dm = {Domain.from-type int}
elseif sdomain == "double" then
set dm = {Domain.from-type double}
}
{self.rfs.append
{RecordField
sname asa String,
domain = dm
}
}
elseif name == "Record" then
let r : #RecordData = {RecordData}
{for i:int=0 below {atts.get-length} do
let lname : #String = {atts.get-local-name i}
let lvalue : #String = {atts.get-value i}
{if lname != null and lvalue != null then
set r[lname asa String] = lvalue
}
}
{self.rs.append r}
}
}
{method public {end-element
uri:String,
name:String,
qname:String
}:void
{if name == "Fields" then
set self.rf = {RecordFields {splice self.rfs}}
set self.rs = {RecordSet self.rf asa RecordFields}
}
}
{method public {error exception:SAXParseException}:void
||{throw exception}
}
{method public {fatal-error exception:SAXParseException}:void
{throw exception}
}
{method public {warning exception:SAXParseException}:void
||{throw exception}
}
}
-----------------------------------------------------------------------
음 소스가 무척 깁니다.
하지만 내용을 살펴보면 역시 아무것도 아니죠.
여기서 중요한건 들어오는 태그 정보에 따라 직접 RecordSet 을 생성한다 것입니다.
자 그럼 하나씩 확인해 볼까요..
-----------------------------------------------------------------------
field public rs : #RecordSet
field public rf : #RecordFields
field public rfs : {Array-of RecordField} = {{Array-of RecordField}}
-----------------------------------------------------------------------
rs 는 생성할 RecordSet이구요.. rf 는 RecordFields 입니다.
rfs 는 RecordField 를 구성할 배열입니다.
-----------------------------------------------------------------------
{method public {get-recordset}:#RecordSet
{return self.rs}
}
-----------------------------------------------------------------------
constructor, start-document, end-document 는 별로 하는일 없습니다.
get-recordset 은 만들어진 RecordSet 을 리턴합니다.
그럼 본격적으로 .. 필드 만드는 부분을 보겠습니다.
여기서 필드 만드는 방법은
start-element 의 태그가 Fields 이면 필드 정의가 이제 부터 나오므로
{self.rfs.clear} 를 호출해서 필드 배열을 비워둡니다.
그리고 Field 태그가 나타나면 각 attributes 값들중에서 name, domain 만 가져다가
필드를 구성한후 rfs 에 추가합니다.
그리고 Field 구성이 다 끝나면
end-element 에서 태그가 Fields 가 나오게 됩니다.
이때는 필드 구성이 완전히 끝난 것이므로
-----------------------------------------------------------------------
{method public {end-element
uri:String,
name:String,
qname:String
}:void
{if name == "Fields" then
set self.rf = {RecordFields {splice self.rfs}}
set self.rs = {RecordSet self.rf asa RecordFields}
}
}
-----------------------------------------------------------------------
레코드셋을 생성합니다.
**컬의 RecordSet 은 필드가 없으면 생성이 안되므로 필드 구성이 완전히 끝난후에 생성합니다.
그리고 각 Record 를 구성합니다.
역시 start-element 에서 태그명이 Record 인것을 골라내면 되겠죠..
이번엔 작업을 쉽게하기위해서
<Record mid="hong1234" mname="홍길동" mcodes="123456-1234351" />
위 처럼 레코드를 구성했습니다. 모두 start-element 에서 attributes 만 읽으면 한 레코드를 구성할
수 있습니다. end-element 를 참조할 필요가 없는 것이죠..
-----------------------------------------------------------------------
let r : #RecordData = {RecordData}
{for i:int=0 below {atts.get-length} do
let lname : #String = {atts.get-local-name i}
let lvalue : #String = {atts.get-value i}
{if lname != null and lvalue != null then
set r[lname asa String] = lvalue
}
}
{self.rs.append r}
-----------------------------------------------------------------------
위와 같은 작업으로 Record 를 추가했습니다.
어렵지 않은 내용이니 설명은 생략합니다.
잘이해가 안되시면 앞쪽의 강좌를 읽어보세요..
마지막으로 예외 처리인데요..
-----------------------------------------------------------------------
{method public {error exception:SAXParseException}:void
||{throw exception}
}
{method public {fatal-error exception:SAXParseException}:void
{throw exception}
}
{method public {warning exception:SAXParseException}:void
||{throw exception}
}
-----------------------------------------------------------------------
위와 같이 fatal-error 에러가 아닌경우는 넘어가게 했습니다.
둥글게 살아야죠.. 너무 빡빡하면 힘드니깐요 ^^;;
소스에 대해 자세히는 설명은 안했지만 어렵지 않으니 한번씩 실행해 보면 쉽게 이해가실 것입니다.
이번 강좌를 마지막으로 진짜로 웹서버와의 만남을 마치겠습니다.
그럼~~
|
|
|
