 vidkid
|
2004-04-22 11:48:32, 조회 : 2,640, 추천 : 324 |
- Download #1 : http3.zip (3.2 KB), Download : 72
[웹서버와의 만남 #4] 데이터를 RecordSet 으로 받기 - 레코드셋에 넣기
안녕하세요. vidkid 입니다.
이번 강좌는 서버로부터 테이블형태의 데이터를 받아 레코드셋에 넣어보겠습니다.
(* 프로젝트 파일은 첨부 파일을 이용해 주세요.)
(start1.curl)
-------------------------------------------------------------------------------------------
{curl 3.0 applet}
{curl-file-attributes character-encoding = "euc-kr"}
{applet manifest = "manifest.mcurl"}
{include "httplib.scurl"}
{value
{HBox
{CommandButton label="GET",
{on Action do
let (result :String, error? : bool) =
{gfGetMethod
{url "http://localhost/study/http3/start1.php?mode=list&no=7"},
{get-character-encoding-by-name "euc-kr"}
}
{popup-message result}
}
}
}
}
-------------------------------------------------------------------------------------------
저번 강좌의 소스에서 GET 방식 버튼만 넣었습니다.
내용은 소스 내용 설명은 생략하구요..
start1.php 내용을 살펴보겠습니다.
(start1.php)
-------------------------------------------------------------------------------------------
<?
echo
"mno,mname,mage,mzipcode,rate
int,String,int,String,double
1,홍길동,100,111-200,4.1
2,강병철과삼태기풀,30,222-121,8.1
3,강호동,74,123-229,1.1
4,서태지,24,123-621,11.3
5,아이들,11,143-527,12.1
6,코코루,33,153-021,8.2
7,갓슈벨,37,173-921,7.3
8,아톰,14,128-121,1.17
9,똘이,24,923-261,1.6
10,태권브이,34,426-331,4.1";
?>
------------------------------------------------------------------------------------------
소스 정렬을 일부러 안했습니다. 쓸데없는 공백을 없앨려구요..
echo 함수로 임의로 만든 데이터를 클라이언트에 전달하는 php 스크립트입니다.
우선 기본적인 전달방식을 정의했습니다.
--------------------------------------------
첫줄에는 필드명을 , 로 나열하고
두번재 줄은 필드의 타입을 , 로 나열합니다.
세번째 줄부터는 각 필드의 데이터 입니다.
--------------------------------------------
꼭 이렇게 해야된는건 아니구 가장 쉬운방법을 택한거니 실제 프로젝트에서는
효율적으로.. 잘.. 정의해서 사용하세요.
(참고로 다음강좌에서는 XML 형태로 정의해서 쓰는 방법을 다뤄보죠.)
실행 결과를 한번 볼까요?
http://localhost/study/http3/start1.curl
또는
C:\APM_Setup\htdocs\study\http3\start1.curl
이렇게 실행하면
위의 화면과 같은 결과가 나옵니다.
php 에서 전달한 데이터가 String 으로 한줄로 표시되어 나왔습니다.
이번에는 전달받은 데이터를 RecordSet 에 넣는 방법을 배워보죠.
(start2.curl)
-------------------------------------------------------------------------------------------
{curl 3.0 applet}
{curl-file-attributes character-encoding = "euc-kr"}
{applet manifest = "manifest.mcurl"}
{import * from CURL.LANGUAGE.REGEXP}
{include "httplib.scurl"}
{value
{HBox
{CommandButton label="GET",
{on Action do
let (result :String, error? : bool) =
{gfGetMethod
{url "http://localhost/study/http3/start1.php?mode=list&no=7"},
{get-character-encoding-by-name "euc-kr"}
}
set result = {regexp-subst "\r", result, "", replace-all?=true}
let rows : StringArray = {result.split split-chars="\n"}
{if rows.size < 2 then
{popup-message result} || 데이터에 문제있음.
{return}
}
|| RecordSet 의 field 만들기
let fields : {Array-of RecordField} = {{Array-of RecordField}}
let names : StringArray = {rows[0].split split-chars=","}
let domains : StringArray = {rows[1].split split-chars=","}
{for i:int=0 below names.size do
let domain : Domain = {Domain.from-type {evaluate domains[i]}}
{fields.append
{RecordField names[i], domain = domain}
}
}
|| RecordData 생성
let rds : {Array-of RecordData} = {{Array-of RecordData}}
{for i:int=2 below rows.size do
||{popup-message rows[i]}
let cols : StringArray = {rows[i].split split-chars=","}
let rd : RecordData = {RecordData}
{for j:int=0 below cols.size do
{if cols[j] == "" then {continue}}
set rd[ fields[j].name] = cols[j]
}
{rds.append rd}
}
|| RecordSet 생성
let rs : RecordSet =
{RecordSet
{RecordFields {splice fields}},
{splice rds}
}
{popup-message {RecordGrid record-source=rs}}
}
}
}
}
-------------------------------------------------------------------------------------------
이번 소스는 좀 되는군요..
start1.php 에서 받아온 데이터를 RecordSet 에 저장하고..
그 내용을 RecordGrid 로 화면에 표시하는 것입니다.
여기에서 중요한건 가져온 데이터를 잘라내서 RecordSet 에 넣는 것이겠죠?
그럼 하나씩 살펴봅시다.
set result = {regexp-subst "\r", result, "", replace-all?=true}
start1.php 에서 받아온 데이터는 result 에 저장이 되어있습니다.
데이터를 쉽게 분리하기 위해서 {regexp-subst} 를 이용해서 \r 을 없애주는 작업을 합니다.
정규식 함수인 regexp-subst 를 사용하기 위해서는
{import * from CURL.LANGUAGE.REGEXP}
를 해줘야 합니다.
다음으로
let rows : StringArray = {result.split split-chars="\n"}
{if rows.size < 2 then
{popup-message result} || 데이터에 문제있음.
{return}
}
는 여러줄의 데이터를 각각의 StringArray 로 만들어 주는 작업을 합니다.
{String.split} 메소드를 이용해서 문자열을 분리할 수 있습니다.
지금 강좌에서 정의한 규칙은 무조건 2줄이 넘어야 하므로 2줄이 아니면 리턴합니다.
이번에는 첫 두줄을 이용해서 RecordSet 의 field 만드는 작업니다.
let fields : {Array-of RecordField} = {{Array-of RecordField}}
let names : StringArray = {rows[0].split split-chars=","}
let domains : StringArray = {rows[1].split split-chars=","}
{for i:int=0 below names.size do
let domain : Domain = {Domain.from-type {evaluate domains[i]}}
{fields.append
{RecordField names[i], domain = domain}
}
}
RecordSet 을 생성할 때 무조건 RecordField 가 존재해야 하므로
{Array-of RecordField} 를 이용해서 배열을 만듭니다.
(*RecordSet 의 Field를 동적으로 생성할 수 있다면 좋겠으나 지원안됨)
names 는 필드명이 들어가고 domains 는 도메인(타입) 이 들어갑니다.
좀더 제대로 할려면 갯수 체크도 해야되는데 여기서는 넘어가겠습니다.
필드를 만들었으니 이번에는 데이터를 만들어 보겠습니다.
데이터는 RecordSet 을 동적으로 생성한후 append 로 추가할 수 있으나
여기서는 배열로 만들어서 넣었습니다.
let rds : {Array-of RecordData} = {{Array-of RecordData}}
{for ... do
...
}
이젠 필드와 레코드 배열이 만들어 졌으니 splice 함수를 이용해서 실제 RecordSet 을
생성합다.
let rs : RecordSet =
{RecordSet
{RecordFields {splice fields}},
{splice rds}
}
어려운 내용이 아니니 이해하기 쉬우실 것입니다.
(**처음 이 내용을 몰랐던 저는 무지 고생했습니다. ^^;)
이번 강좌는 간단히 , 로 분리된 데이터를 RecordSet 에 넣는 것까지 했습니다.
이것만 있으면 서버와의 통신은 거의 90% 이상이 다 끝났다고해도 과언이 아닙니다.
어떤 실행의 결과..예를 들면 삭제라던가.. 하는 부분도 위와같이 정하신후
RecordSet 으로 받아서 성공/실패 여부를 판단할 수 있겠죠.
그 응용은 여러분들에게 맡기구요.
이 강좌가 서버와의 만남 마지막 강좌입니다.
그럼~~
|
|
|
