 vidkid
|
2004-04-21 17:59:42, 조회 : 3,945, 추천 : 485 |
- Download #1 : http2.zip (2.1 KB), Download : 102
[웹서버와의 만남 #3] 데이터를 RecordSet 으로 받기 - 프로시저 만들기
안녕하세요. vidkid 입니다.
이번에는 서버로부터 테이블 형태의 데이터를 받아서 클라이언트에 표시해주는
공부를 해보죠..
(* 프로젝트 파일은 첨부 파일을 이용해 주세요.)
이전 강좌에서는 서버에있는 php 를 호출해서 데이터를 받아 오는 것까지 했습니다.
외울 필요도 없고 프로시저로 만들어서 사용하면 편리하게 사용하고 쉽게 사용할 수 있습니다.
그래서 우선적으로 GET 과 POST 를 지원하는 프로시저 두개를 만들었습니다.
httplib.scurl 파일을 IDE 로 열어보시면 2개의 프로시져가 있습니다.
하나씩 내용을 살펴보겠습니다.
(httplib.scurl 의 gfGetMethod 프로시져)
-------------------------------------------------------------------------------------------
{define-proc public {gfGetMethod query-url : Url, charset : CharEncoding }:(String, bool)
let string-buf : StringBuf = {new StringBuf}
let num-read : int = 0
let error? : bool = false
let result : String = ""
{try
{with-file-caching-style FileCachingStyle.reload do
set (string-buf, num-read) = {read-from character-encoding = charset, query-url}
}
catch th:Throwable do
let str : String = th.value
{if {str.find-string "403"} >= 0 then
set string-buf = {StringBuf "403"}
set error? = true
elseif {str.find-string "404"} >= 0 then
set string-buf = {StringBuf "404"}
set error? = true
else
set string-buf = {StringBuf "100"}
set error? = true
}
}
set result = {string-buf.to-String}
{return result, error? }
}
-------------------------------------------------------------------------------------------
이전 강좌에서 GET 방식으로 데이터를 가져오기 위한 부분을 프로시져로 만든 소스입니다.
대부분 친숙한 소스라 생각되네요.
이번엔
{try
...
catch th:Throwable do
...
}
의 catch 부분에 많은 코드가 들어갔습니다.
이 내용은 서버로부터 html body 의 내용(th:Throwable 의 내용) 에 404, 403 에러가
나온경우를 체크하기우한 코드입니다.
별로 좋은 방법은 아니지만 대부분의 경우 잘 동작합니다.
404 는 대부분 아시다시피 해당 url 에 파일이 없는 경우이고,
403 은 session 을 사용해서 로그인 관리를 하다가 서버가 restart 된경우 session 이 없어지면서
나오는 에러입니다.
이 프로시져는 2개의 값을 리턴합니다. 이건 그냥 참조하세요.
별로 어려운 내용이 아니니깐 넘어가겠습니다.
(httplib.scurl 의 gfGetMethod 프로시져)
-------------------------------------------------------------------------------------------
{define-proc public {gfPostMethod query-url : Url, charset : CharEncoding, ... }:(String, bool)
let error? : bool = false
let script-loc:Url = query-url
let http-file:HttpFile = {script-loc.instantiate-File} asa HttpFile
let req:HttpFormData = {HttpFormData
mime-type = HttpFormData.urlencoded-mime-type,
default-character-encoding=charset
}
{for param : HttpFormStringParam in ... do
{req.append param}
}
let web-stream:#HttpTextInputStream
{with-file-caching-style FileCachingStyle.reload do
set web-stream =
{http-file.http-read-open
character-encoding=charset,
request-data = req,
request-method = HttpRequestMethod.post
}
}
let returned : String = ""
let lines:{Array-of StringBuf} = {{Array-of StringBuf}}
let n-lines:int = 0
{try
||set gGlobalErrorCode = ""
set (lines, n-lines) = {web-stream.read-lines}
catch th:Throwable do
let str : String = th.value
{if {str.find-string "403"} >= 0 then
set returned = "403"
set error? = true
elseif {str.find-string "404"} >= 0 then
set returned = "404"
set error? = true
else
set returned = "100"
set error? = true
}
finally
{web-stream.close}
}
{if not error? then
{for i :int=0 below n-lines do
set returned = returned & "\n" & {lines[i].to-String}
}
}
{return returned, error?}
}
-------------------------------------------------------------------------------------------
이번엔 POST 메소드입니다.
역시 이전 강좌를 읽으셨다면 친근한 소스입니다.
좀 특이한 점은
{define-proc public {gfPostMethod query-url : Url, charset : CharEncoding, ... }:(String, bool)
|| 생략
}
위와 같이 argument 로 ... (rest arguments) 를 받았다는 것입니다.
이것은 gfPostMethod 를 사용할때 POST 방식으로 넘겨질 파라메터를 직접 받기위해서 사용한 것입니다.
뒤에 무엇이 들어오던지 받겠다는 의미겠죠..
여기서는 HttpFormStringParam 클래스 객체의 파라메터를 받습니다.
{for param : HttpFormStringParam in ... do
{req.append param}
}
바로 이 부분이 ... 안에서 HttpFormStringParam 를 받아서 req 에 추가하는 부분입니다.
만약 여러분께서 사용하신다면..
{gfPostMethod {url "test.php"}, {get-character-encoding-by-name "euc-kr"},
{HttpFormStringParam "mode", "list"},
{HttpFormStringParam "no", "7"}
}
위와 같이 사용할 수 있습니다.
참 편리합니다. ^^;
나머지 소스는 이전과 같으니 생략하겠습니다.
한번 어떻게 쓰는지 예제를 확인해 볼까요..
(start1.curl)
-------------------------------------------------------------------------------------------
{curl 3.0 applet}
{curl-file-attributes character-encoding = "euc-kr"}
{applet manifest = "manifest.mcurl"}
{include "httplib.scurl"}
{value
{HBox
{CommandButton label="GET",
{on Action do
let (result :String, error? : bool) =
{gfGetMethod
{url "http://localhost/study/http2/start1.php?mode=list&no=7"},
{get-character-encoding-by-name "euc-kr"}
}
{popup-message result}
}
},
{CommandButton label="POST",
{on Action do
let (result :String, error? : bool) =
{gfPostMethod
{url "http://localhost/study/http2/start1.php"},
{get-character-encoding-by-name "euc-kr"},
{HttpFormStringParam "mode", "list"},
{HttpFormStringParam "no", "7"}
}
{popup-message result}
}
}
}
}
-------------------------------------------------------------------------------------------
소스는 CommandButton 두개를 사용합니다. 각각 GET 과 POST 입니다.
소스를 넣었더니 길어졌네요..
이 강좌는 이걸로 하고..
다음 강좌에서 뵙죠..^^
|
|
|
